Hijriah

Konversi masehi ke Pasaran Jawa dan Hijriah dengan metode Julian Date

 Asep Kurniawan

Julian Date

Julian date adalah tetapan bilangan penanggalan matahari yang dihitung semenjak siang tanggal 1 Januari 4713 SM.

Penanggalan Hijriah

Tanggal 1 Muharram tahun pertama sama dengan bilangan Julian 1948439.5.

Penanggalan Jawa

Sistem Pasaran Jawa memadukan metode penanggalan Hindu, Hijriah dan Julian. Keistimewaan lainnya adalah memiliki siklus pekan, siklus pasaran, siklus wuku, siklus windu.

Sketch program konversi masehi ke pasaran jawa dan Hijriah:

#define epochHijriah          1948439.5f //math.harvard.edu
#define tambahKurangHijriah   0

struct TanggalDanWaktu
{
  uint8_t detik;
  uint8_t menit;
  uint8_t jam;
  uint8_t hari;
  uint8_t tanggal;
  uint8_t bulan;
  uint8_t tahun;
};
struct Tanggal
{
  uint8_t tanggal;
  uint8_t bulan;
  uint16_t tahun;
};
struct TanggalJawa
{
  uint8_t pasaran;
  uint8_t wuku;
  uint8_t tanggal;
  uint8_t bulan;
  uint16_t tahun;
};
struct JamDanMenit
{
  uint8_t jam;
  uint8_t menit;
};

uint8_t jumlahHariPerBulan[] = { 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31 };
char namaBulanMasehi[][10] = {"Januari", "Februari", "Maret", "April", "Mei", "Juni", "Juli", "Agustus", "September", "Oktober",
                            "November", "Desember"
                           };
char namaHariMasehi[][7] = {"Minggu", "Senin", "Selasa", "Rabu", "Kamis", "Jum'at", "Sabtu",};
char namaBulanHijriah[][14] = {"Muharram", "Safar", "Rabiul awal", "Rabiul akhir", "Jumadil awal", "Jumadil akhir", "Rajab",
                             "Sya'ban", "Ramadhan", "Syawal", "Dzulkaidah", "Dzulhijjah"
                            };
char namaBulanJawa[][12] = { "Sura", "Sapar", "Mulud", "Bakda Mulud", "Jumadilawal", "Jumadilakir", "Rejeb", "Ruwah", "Pasa",
                           "Sawal", "Sela", "Besar"
                         };
char namaWukuJawa[][13] = {"Shinta", "Landhep", "Wukit", "Kurantil", "Tala", "Gumbreg", "Warigalit", "Warigagung", "Julungwangi",
                         "Sungsang", "Galungan", "Kuningan", "Langkir", "Mandasia", "Julungpujut", "Pahang", "Kuruwelut", "Mrakeh", "Tambir",
                         "Madangkungan", "Maktal", "Wuye", "Manahil", "Prangbakat", "Bala", "Wungu", "Wayang", "Kulawu", "Dhukut", "Watugunung"
                        };
char namaHariPasaran[][7] = {"Legi", "Pahing", "Pon", "Wage", "Kliwon"};

TanggalDanWaktu tanggalMasehi;
Tanggal tanggalHijriah;
TanggalJawa tanggalJawa;
JamDanMenit waktuMagrib;

void setup() {
  Serial.begin(9600);
  Serial.println("Konversi Penanggalan Masehi ke Hijriah (metode Julian)");
  Serial.println("https://www.semesin.com/project/");
  Serial.println();
}

void loop() {
  waktuMagrib = {18, 12};

  uint32_t jumlahHari;
  double jumlahHariMatahari;

  tanggalMasehi.jam = 12;
  tanggalMasehi.menit = 0;
  tanggalMasehi.detik = 0;

  tanggalMasehi.tanggal = 8;
  tanggalMasehi.bulan = 9;
  tanggalMasehi.tahun = 18;

  tanggalMasehi.hari = hariDariTanggal(tanggalMasehi);
  masehiKeHijriah(tanggalMasehi, waktuMagrib, tambahKurangHijriah, tanggalHijriah, tanggalJawa);
  printKonversi(tanggalMasehi, tanggalHijriah, tanggalJawa);

  tanggalMasehi.tanggal = 9;
  tanggalMasehi.bulan = 9;
  tanggalMasehi.tahun = 18;

  tanggalMasehi.hari = hariDariTanggal(tanggalMasehi);
  masehiKeHijriah(tanggalMasehi, waktuMagrib, tambahKurangHijriah, tanggalHijriah, tanggalJawa);
  printKonversi(tanggalMasehi, tanggalHijriah, tanggalJawa);

  tanggalMasehi.tanggal = 10;
  tanggalMasehi.bulan = 9;
  tanggalMasehi.tahun = 18;

  tanggalMasehi.hari = hariDariTanggal(tanggalMasehi);
  masehiKeHijriah(tanggalMasehi, waktuMagrib, tambahKurangHijriah, tanggalHijriah, tanggalJawa);
  printKonversi(tanggalMasehi, tanggalHijriah, tanggalJawa);

  tanggalMasehi.tanggal = 11;
  tanggalMasehi.bulan = 9;
  tanggalMasehi.tahun = 18;

  tanggalMasehi.hari = hariDariTanggal(tanggalMasehi);
  masehiKeHijriah(tanggalMasehi, waktuMagrib, tambahKurangHijriah, tanggalHijriah, tanggalJawa);
  printKonversi(tanggalMasehi, tanggalHijriah, tanggalJawa);

  tanggalMasehi.tanggal = 12;
  tanggalMasehi.bulan = 9;
  tanggalMasehi.tahun = 18;

  tanggalMasehi.hari = hariDariTanggal(tanggalMasehi);
  masehiKeHijriah(tanggalMasehi, waktuMagrib, tambahKurangHijriah, tanggalHijriah, tanggalJawa);
  printKonversi(tanggalMasehi, tanggalHijriah, tanggalJawa);

  while (1);
}

double get_julian_date(Tanggal tanggal)
{
  if (tanggal.bulan <= 2)
  {
    tanggal.tahun -= 1;
    tanggal.bulan += 12;
  }

  double a = floor(tanggal.tahun / 100.0);
  double b = 2 - a + floor(a / 4.0);

  if (tanggal.tahun < 1583)
    b = 0;
  if (tanggal.tahun == 1582) {
    if (tanggal.bulan > 10)
      b = -10;
    if (tanggal.bulan == 10) {
      b = 0;
      if (tanggal.tanggal > 4)
        b = -10;
    }
  }

  return floor(365.25 * (tanggal.tahun + 4716)) + floor(30.6001 * (tanggal.bulan + 1)) + tanggal.tanggal + b - 1524.5;
}

double konversiTanggalHijriahKeJulianDate(uint16_t tahun, uint8_t bulan, uint8_t tanggal)
{
  return (epochHijriah + tanggal + ceil(29.5 * (bulan - 1)) + (354L * (tahun - 1)) + floor((3 + (11 * tahun)) / 30)) - 1;
}

void masehiKeHijriah(TanggalDanWaktu masehi, JamDanMenit waktuSholatMagrib, int8_t koreksiHijriah, Tanggal &hijriah, TanggalJawa &jawa)
{
  uint16_t sisaHari;
  double julianDate = get_julian_date({masehi.tanggal, masehi.bulan, masehi.tahun + 2000});

  uint16_t menitMagrib = waktuSholatMagrib.jam * 60  + waktuSholatMagrib.menit;
  uint16_t menitSekarang = masehi.jam * 60 + masehi.menit;

  if (menitSekarang >= menitMagrib)
  {
    julianDate++;//Pergantian hari hijrah pada magrib
  }

  julianDate = floor(julianDate) + 0.5;

  Tanggal tanggalHijriah;

  hijriah.tahun = floor(((30 * (julianDate - epochHijriah)) + 10646) / 10631);
  hijriah.bulan = min(12.0, ceil((julianDate - (29 + konversiTanggalHijriahKeJulianDate(hijriah.tahun, 1, 1))) / 29.5) + 1);
  hijriah.tanggal = (julianDate - konversiTanggalHijriahKeJulianDate(hijriah.tahun, hijriah.bulan, 1)) + 1;

  long julianLong = (long)julianDate;
  jawa.pasaran = ((julianLong + 1) % 5); //0 = legi
  jawa.wuku = (((julianLong + 65) % 210) / 7); //0 = Shinta
  jawa.tanggal = hijriah.tanggal;
  jawa.bulan = hijriah.bulan;
  jawa.tahun = hijriah.tahun + 512;

}
uint8_t hariDariTanggal(TanggalDanWaktu tanggalDanWaktu) {
  uint16_t jumlahHari = tanggalDanWaktu.tanggal;
  for (uint8_t i = 1; i < tanggalDanWaktu.bulan; ++i)
    jumlahHari += jumlahHariPerBulan[i-1];
  if (tanggalDanWaktu.bulan > 2 && tanggalDanWaktu.tahun % 4 == 0)
    ++jumlahHari;
  jumlahHari += (365 * tanggalDanWaktu.tahun) + ((tanggalDanWaktu.tahun + 3) / 4) - 1;

  return ((jumlahHari + 6) % 7) + 1; // 1 Januari 2000 hari sabtu = 7
}

void printKonversi(TanggalDanWaktu tanggalMasehi, Tanggal tanggalHijriah, TanggalJawa tanggalJawa)
{
  Serial.print("Masehi :\t");
  Serial.print(namaHariMasehi[tanggalMasehi.hari-1]);
  Serial.print(", ");
  Serial.print(tanggalMasehi.tanggal);
  Serial.print(" ");
  Serial.print(namaBulanMasehi[tanggalMasehi.bulan - 1]);
  Serial.print(" ");
  Serial.println(tanggalMasehi.tahun + 2000);

  Serial.print("Hijriah :\t");
  Serial.print(tanggalHijriah.tanggal);
  Serial.print(" ");
  Serial.print(namaBulanHijriah[tanggalHijriah.bulan - 1]);
  Serial.print(" ");
  Serial.println(tanggalHijriah.tahun);

  Serial.print("Pasaran Jawa :\t");
  Serial.print(tanggalJawa.tanggal);
  Serial.print(" ");
  Serial.print(namaHariPasaran[tanggalJawa.pasaran]);
  Serial.print(", ");
  Serial.print(namaWukuJawa[tanggalJawa.wuku]);
  Serial.print(", ");
  Serial.print(namaBulanJawa[tanggalJawa.bulan - 1]);
  Serial.print(" ");
  Serial.println(tanggalJawa.tahun);
  Serial.println();
}

 

Konversi penanggalan Masehi ke Hijriah menggunakan Arduino

 Asep Kurniawan

Penanggalan masehi mengacu pada peredaran matahari, satu tahun masehi terhitung sebesar 365,25 hari, sedangkan Kalender hijriah mengacu pada peredaran bulan, waktu 12 kali peredaran bulan terhitung sebesar 354,367068 hari.
Untuk konversi masehi ke hijriah mengikuti kaidah berikut ini :

  1. Basis perhitungan Masehi ditetapkan pada 18 April 1999.
  2. Basis perhitungan Hijriah ditetapkan pada 1 Muharram 1420.
  3. Jumlah hari dalam satu bulan Hijriah adalah: 30, 29, 30, 29, 30, 29, 30, 29, 30, 29, 30, 29(30).
  4. Berlaku dari jam 00.00 hingga waktu Maghrib karena penanggalan Hijriah berganti hari pada waktu Maghrib

penerapan dalam Arduino bisa menggunakan program/sketch berikut ini:

double tahunBulan = 354.367068;
double tahunMatahari = 365.25;

String namaBulanHijriah[] = {"Muharram","Safar","Rabiul awal","Rabiul akhir","Jumadil awal","Jumadil akhir","Rajab","Sya'ban","Ramadhan","Syawal","Dzulkaidah","Dzulhijjah"};
String namaBulanMasehi[] = {"Januari","Februari","Maret","April","Mei","Juni","Juli","Agustus","September","Oktober","November","Desember"};
uint16_t jumlahHariPerBulanHijriah[] = {0,30,59,89,118,148,177,207,236,266,295,325,354};
uint16_t jumlahHariPerBulanMasehi[]={0,31,59,90,120,151,181,212,243,273,304,334};

void setup() {
  Serial.begin(9600);
  Serial.println("Konversi Penanggalan Masehi ke Hijriah");
  Serial.println("http://www.semesin.com/project");
}

void loop() {
  uint32_t jumlahHari;
  double jumlahHariMatahari;
  
  byte tanggalMasehi = 16;
  byte bulanMasehi = 3;
  uint16_t tahunMasehi = 2018;

  byte tanggalHijriah;
  byte bulanHijriah;
  uint16_t tahunHijriah;

  jumlahHari = jumlahHariDariTanggal(tanggalMasehi, bulanMasehi, tahunMasehi - 2000);
  masehiKeHijriah(jumlahHari, &tanggalHijriah, &bulanHijriah, &tahunHijriah);

  Serial.print(tanggalMasehi);
  Serial.print(" ");
  Serial.print(namaBulanMasehi[bulanMasehi-1]);
  Serial.print(" ");
  Serial.print(tahunMasehi);

  Serial.print(" == ");

  Serial.print(tanggalHijriah);
  Serial.print(" ");
  Serial.print(namaBulanHijriah[bulanHijriah-1]);
  Serial.print(" ");
  Serial.println(tahunHijriah);

  while(1);
}

//tanggal mulai dari 1
//bulan mulai dari 1
//tahun dua digit
//minggu = 1, sabtu = 7
//base 18 April 1999
uint32_t jumlahHariDariTanggal(byte tanggal, byte bulan, uint16_t tahun)
{
  uint32_t jumlahHari = (uint32_t)tahun * 365;
  for (uint16_t i = 0; i < tahun; i++) 
  {
    if (!(i%4))
    {
      jumlahHari++;
    }
  }
  jumlahHari += jumlahHariPerBulanMasehi[bulan-1];
  if ( (bulan >= 2) && !(tahun % 4)) 
  { 
    jumlahHari++;
  }
  jumlahHari+= tanggal;
  return jumlahHari + 259;// base 18 April 1999
}

void masehiKeHijriah(uint32_t HariMasehi, byte *tanggal, byte *bulan, uint16_t *tahun)
{
  uint16_t sisaHari;
  *tahun = floor(HariMasehi/tahunBulan);
  sisaHari = HariMasehi - (tahunBulan * *tahun);

  for(byte i=0;i<sizeof(jumlahHariPerBulanHijriah);i++)
  {
    if(sisaHari <= jumlahHariPerBulanHijriah[i])
    {
      sisaHari -= jumlahHariPerBulanHijriah[i-1];
      *bulan = i;
      break;
    }
  }
  *tanggal = sisaHari;
  *tahun += 1420;
}

hasil keluaran di serial monitor:

Catatan : metode ini memiliki kekurangan yaitu menghitung penanggalan Hijriah dengan jumlah bulan yang tetap (hanya bagus untuk mengenal prinsip konversi) untuk konversi yang lebih presisi bisa menggunakan metode Julian Date :
Konversi masehi ke Pasaran Jawa dan Hijriah dengan metode Julian Date